$!-----------------------------------------------------------------------------
$! BUILD_LOOKUPAGENT.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 01-JUN-2021  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""LOOKUPAGENT""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ VMS_VERSION = F$INTEGER(F$EXTRACT(1,1,F$GETSYI("VERSION"))) * 10 +-
                F$INTEGER(F$EXTRACT(3,1,F$GETSYI("VERSION")))
$ IF VMS_VERSION .LT. 73
$ THEN
$    WRITE SYS$OUTPUT "BUILD: requires a minimum of VMS V7.3"
$    EXIT
$ ENDIF
$!
$ SSL = ""
$ IF F$SEARCH("SSL$INCLUDE:*.H") .NES. "" .AND. -
     F$SEARCH("SYS$COMMON:[SYSLIB]SSL$LIBSSL_SHR32.EXE") .NES. "" .AND. -
     F$SEARCH("SYS$COMMON:[SYSLIB]SSL$LIBCRYPTO_SHR32.EXE") .NES. "" -
     THEN SSL = "SSL"
$ IF F$SEARCH("SSL1$INCLUDE:*.H") .NES. "" .AND. -
     F$SEARCH("SYS$COMMON:[SYSLIB]SSL1$LIBSSL_SHR32.EXE") .NES. "" .AND. -
     F$SEARCH("SYS$COMMON:[SYSLIB]SSL1$LIBCRYPTO_SHR32.EXE") .NES. "" -
     THEN SSL = "SSL1"
$ IF SSL .EQS. ""
$ THEN
$    WRITE SYS$OUTPUT "BUILD: requires SSL[1] product to be installed and started"
$    EXIT
$ ENDIF
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$ INCLUDES = " /INCLUDE=[SRC.MISC]"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW))"
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' LOOKUPAGENT
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    CGILIB_OBJ = "[SRC.MISC.OBJ_''ARCH_NAME']CGILIB.OBJ"
$    SET NOON
$    SET VERIFY
$    LINK /NOTRACE /EXECUTABLE=WASD_EXE:LOOKUPAGENT.EXE -
     'OBJECT_DIR'LOOKUPAGENT,'CGILIB_OBJ'
$!   F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------