$!-----------------------------------------------------------------------------
$! BUILD_LIBZ.COM
$!
$! https://www.zlib.net
$! zlib 1.3.1
$! zlib software copyright (c) 1995-2024 Jean-loup Gailly and Mark Adler
$! 
$! https://www.zlib.net/zlib131.zip
$! unzip "-j" zlib131.zip */*.c -x */*/*.c
$! unzip "-j" zlib131.zip */*.h -x */*/*.h
$!
$! edit gzguts.c to insert:
$!| #ifdef __VMS
$!| #  include <unistd.h>
$!| #  include <unixio.h>
$!| #endif
$! immediately following:
$!| #ifdef STDC
$!| #  include <string.h>
$!| #  include <stdlib.h>
$!| #  include <limits.h>
$!| #endif
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 01-SEP-2024  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ on controly then exit 44
$ on error then continue
$!
$ @wasd_root:[src]archer.com "LIBZ"
$!
$ p1 = f$edit(p1,"upcase")
$ p2 = f$edit(p2,"upcase")
$ p3 = f$edit(p3,"upcase")
$!
$ defines = " /define=(__VMS_VER=70000000,__CRTL_VER=70000000,STDC)"
$!
$ includes = ""
$ warnings=  " /warning=(disable=(preoptw))"
$!
$ cc_options = "/decc /optimize /stand=relaxed /prefix=all /names=upper" +-
               includes + defines + warnings
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "COMPILE"
$ then
$    delete /noconfirm 'object_dir'*.obj;* 
$    set verify
$ cc 'cc_options' /object='object_dir'adler32  adler32
$ cc 'cc_options' /object='object_dir'compress compress
$ cc 'cc_options' /object='object_dir'crc32    crc32
$ cc 'cc_options' /object='object_dir'deflate  deflate
$ cc 'cc_options' /object='object_dir'gzclose  gzclose
$ cc 'cc_options' /object='object_dir'gzlib    gzlib
$ cc 'cc_options' /object='object_dir'gzread   gzread
$ cc 'cc_options' /object='object_dir'gzwrite  gzwrite
$ cc 'cc_options' /object='object_dir'infback  infback
$ cc 'cc_options' /object='object_dir'inffast  inffast
$ cc 'cc_options' /object='object_dir'inflate  inflate
$ cc 'cc_options' /object='object_dir'inftrees inftrees
$ cc 'cc_options' /object='object_dir'trees    trees
$ cc 'cc_options' /object='object_dir'uncompr  uncompr
$ cc 'cc_options' /object='object_dir'zutil    zutil
$!   'f$verify(0)
$    set on
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "BUILD" .or. p1 .eqs. "LINK"
$ then
$    set verify
$ link /notrace /nodebug /share=wasd_exe:wasd_libz_shr32.exe -
       /SEGMENT=CODE=P0 -
       'object_dir'adler32,compress,crc32,deflate,gzclose,gzlib,gzread,-
       gzwrite,infback,inffast,inflate,inftrees,trees,uncompr,zutil,-
       sys$input:/options
case_sensitive=YES
identification = "WASD_LIBZ_SHR32"
build = "V1.3.1"
symbol_vector = (DEFLATE=PROCEDURE)
symbol_vector = (DEFLATEINIT2_=PROCEDURE)
symbol_vector = (DEFLATEEND=PROCEDURE)
symbol_vector = (INFLATE=PROCEDURE)
symbol_vector = (INFLATEINIT2_=PROCEDURE)
symbol_vector = (INFLATEEND=PROCEDURE)
symbol_vector = (ZLIBVERSION=PROCEDURE)
$!   'f$verify(0)
$ endif
$!
$!-----------------------------------------------------------------------------