$!-----------------------------------------------------------------'f$verify(0)
$! TEST_ACME_TLS_1.COM
$!
$! 27-DEC-2024  MGD  initial
$!-----------------------------------------------------------------------------
$ on error then continue
$!
$ if P1 .eqs. ""
$ then
$    write sys$output "USAGE: @TEST_ACME_TLS_1 host1[,host2[,host3,host4...]]"
$    exit
$ endif
$!
$ openssl = ""
$ if f$trnlnm("SSL3$ROOT") .nes. "" then openssl = "SSL3$EXE:OPENSSL.EXE" 
$ if f$trnlnm("SSL31$ROOT") .nes. "" then openssl = "SSL31$EXE:OPENSSL.EXE" 
$ if f$trnlnm("SSL32$ROOT") .nes. "" then openssl = "SSL32$EXE:OPENSSL.EXE" 
$ if f$search("''openssl'") .eqs. "" then openssl = ""
$ if openssl .eqs. ""
$ then
$    write sys$output "ERROR: OPENSSL.EXE not located"
$    exit
$ endif
$ openssl = "$" + openssl - ".EXE"
$!
$ write sys$output "EXPECT: ""...unexpected eof while reading..."" failures"
$ next = -1
$ host_loop:
$    next = next + 1
$    host = f$element(next,",",P1)
$    if (host .eqs. ",") then goto end_host_loop
$    test = "''openssl' s_client -connect ''host':443 -servername ''host' " +-
            "-alpn ""acme-tls/1"""
$    define /user sys$output nl:
$    define /user sys$input nl:
$    set verify
$ 'test'
$!   'f$verify(0)
$    goto host_loop
$ end_host_loop:
$!-----------------------------------------------------------------------------